home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / pctj8505.arc / OSCILL.BAS < prev    next >
BASIC Source File  |  1986-09-14  |  2KB  |  45 lines
  1. 10 ' PC OSCILLOSCOPE -- Copyright 1984 Michael A. Covington
  2. 20 ' A graphics adaptation of PC Voltmeter.
  3. 30 ' Requires the same input and calibration procedure.
  4. 50 CLS : KEY OFF
  5. 60 PRINT:PRINT "PC OSCILLOSCOPE"
  6. 80 PRINT "Connect first calibration voltage, ";
  7. 85 PRINT "then press any key."
  8. 90 IF INKEY$="" THEN 90
  9. 100 READING1 = 1/STICK(0)
  10. 110 PRINT:PRINT "Reading taken."
  11. 130 INPUT "Value of that voltage (in volts)";VOLTAGE1
  12. 140 PRINT
  13. 150 PRINT "Connect second calibration voltage, ";
  14. 155 PRINT "then press any key."
  15. 160 IF INKEY$="" THEN 160
  16. 170 READING2 = 1/STICK(0)
  17. 180 PRINT:PRINT "Reading taken."
  18. 200 INPUT "Value of that voltage (in volts)";VOLTAGE2
  19. 210 FACTOR = (READING2-READING1)/(VOLTAGE2-VOLTAGE1)
  20. 220 OFFSET = READING2 - (VOLTAGE2*FACTOR)
  21. 230 PRINT "Calibrated"
  22. 240 PRINT:PRINT
  23. 260 PRINT "Press any key to start."
  24. 270 PRINT "A beep will signal that the trace is"
  25. 280 PRINT "complete; you may then press any key"
  26. 290 PRINT "to start another one."
  27. 300 IF INKEY$="" THEN 300
  28. 310 SCREEN 1,0 : CLS
  29. 320 LINE (0,0)-(320,0)
  30. 330 LINE -(320,200)
  31. 340 LINE -(0,200)
  32. 350 LINE -(0,0)
  33. 360 LOCATE 2,2:PRINT "PC Oscilloscope"
  34. 370 X=10
  35. 380 WHILE X<301
  36. 390   VOLTAGE = ((1/STICK(0))-OFFSET)/FACTOR
  37. 400   IF VOLTAGE>5 THEN VOLTAGE=5
  38. 410   IF VOLTAGE<0 THEN VOLTAGE=0
  39. 420   Y = 185 - 30*VOLTAGE
  40. 430   PSET(X,Y)
  41. 440   X=X+1
  42. 450 WEND
  43. 460 BEEP
  44. 470 IF INKEY$="" THEN 470 ELSE 310
  45.